home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 2010 April / PCWorld0410.iso / hity wydania / Ubuntu 9.10 PL / karmelkowy-koliberek-desktop-9.10-i386-PL.iso / casper / filesystem.squashfs / usr / bin / pod2text < prev    next >
Text File  |  2009-10-01  |  8KB  |  248 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.         if $running_under_some_shell;
  4.  
  5. # pod2text -- Convert POD data to formatted ASCII text.
  6. #
  7. # Copyright 1999, 2000, 2001, 2004, 2006 by Russ Allbery <rra@stanford.edu>
  8. #
  9. # This program is free software; you may redistribute it and/or modify it
  10. # under the same terms as Perl itself.
  11. #
  12. # The driver script for Pod::Text, Pod::Text::Termcap, and Pod::Text::Color,
  13. # invoked by perldoc -t among other things.
  14.  
  15. require 5.004;
  16.  
  17. use Getopt::Long qw(GetOptions);
  18. use Pod::Text ();
  19. use Pod::Usage qw(pod2usage);
  20.  
  21. use strict;
  22.  
  23. # Silence -w warnings.
  24. use vars qw($running_under_some_shell);
  25.  
  26. # Take an initial pass through our options, looking for one of the form
  27. # -<number>.  We turn that into -w <number> for compatibility with the
  28. # original pod2text script.
  29. for (my $i = 0; $i < @ARGV; $i++) {
  30.     last if $ARGV[$i] =~ /^--$/;
  31.     if ($ARGV[$i] =~ /^-(\d+)$/) {
  32.         splice (@ARGV, $i++, 1, '-w', $1);
  33.     }
  34. }
  35.  
  36. # Insert -- into @ARGV before any single dash argument to hide it from
  37. # Getopt::Long; we want to interpret it as meaning stdin (which Pod::Simple
  38. # does correctly).
  39. my $stdin;
  40. @ARGV = map { $_ eq '-' && !$stdin++ ? ('--', $_) : $_ } @ARGV;
  41.  
  42. # Parse our options.  Use the same names as Pod::Text for simplicity, and
  43. # default to sentence boundaries turned off for compatibility.
  44. my %options;
  45. $options{sentence} = 0;
  46. Getopt::Long::config ('bundling');
  47. GetOptions (\%options, 'alt|a', 'code', 'color|c', 'help|h', 'indent|i=i',
  48.             'loose|l', 'margin|left-margin|m=i', 'overstrike|o',
  49.             'quotes|q=s', 'sentence|s', 'termcap|t', 'width|w=i') or exit 1;
  50. pod2usage (1) if $options{help};
  51.  
  52. # Figure out what formatter we're going to use.  -c overrides -t.
  53. my $formatter = 'Pod::Text';
  54. if ($options{color}) {
  55.     $formatter = 'Pod::Text::Color';
  56.     eval { require Term::ANSIColor };
  57.     if ($@) { die "-c (--color) requires Term::ANSIColor be installed\n" }
  58.     require Pod::Text::Color;
  59. } elsif ($options{termcap}) {
  60.     $formatter = 'Pod::Text::Termcap';
  61.     require Pod::Text::Termcap;
  62. } elsif ($options{overstrike}) {
  63.     $formatter = 'Pod::Text::Overstrike';
  64.     require Pod::Text::Overstrike;
  65. }
  66. delete @options{'color', 'termcap', 'overstrike'};
  67.  
  68. # Initialize and run the formatter.
  69. my $parser = $formatter->new (%options);
  70. do {
  71.     my ($input, $output) = splice (@ARGV, 0, 2);
  72.     $parser->parse_from_file ($input, $output);
  73. } while (@ARGV);
  74.  
  75. __END__
  76.  
  77. =head1 NAME
  78.  
  79. pod2text - Convert POD data to formatted ASCII text
  80.  
  81. =head1 SYNOPSIS
  82.  
  83. pod2text [B<-aclost>] [B<--code>] [B<-i> I<indent>] S<[B<-q> I<quotes>]>
  84. S<[B<-w> I<width>]> [I<input> [I<output> ...]]
  85.  
  86. pod2text B<-h>
  87.  
  88. =head1 DESCRIPTION
  89.  
  90. B<pod2text> is a front-end for Pod::Text and its subclasses.  It uses them
  91. to generate formatted ASCII text from POD source.  It can optionally use
  92. either termcap sequences or ANSI color escape sequences to format the text.
  93.  
  94. I<input> is the file to read for POD source (the POD can be embedded in
  95. code).  If I<input> isn't given, it defaults to STDIN.  I<output>, if given,
  96. is the file to which to write the formatted output.  If I<output> isn't
  97. given, the formatted output is written to STDOUT.  Several POD files can be
  98. processed in the same B<pod2text> invocation (saving module load and compile
  99. times) by providing multiple pairs of I<input> and I<output> files on the
  100. command line.
  101.  
  102. =head1 OPTIONS
  103.  
  104. =over 4
  105.  
  106. =item B<-a>, B<--alt>
  107.  
  108. Use an alternate output format that, among other things, uses a different
  109. heading style and marks C<=item> entries with a colon in the left margin.
  110.  
  111. =item B<--code>
  112.  
  113. Include any non-POD text from the input file in the output as well.  Useful
  114. for viewing code documented with POD blocks with the POD rendered and the
  115. code left intact.
  116.  
  117. =item B<-c>, B<--color>
  118.  
  119. Format the output with ANSI color escape sequences.  Using this option
  120. requires that Term::ANSIColor be installed on your system.
  121.  
  122. =item B<-i> I<indent>, B<--indent=>I<indent>
  123.  
  124. Set the number of spaces to indent regular text, and the default indentation
  125. for C<=over> blocks.  Defaults to 4 spaces if this option isn't given.
  126.  
  127. =item B<-h>, B<--help>
  128.  
  129. Print out usage information and exit.
  130.  
  131. =item B<-l>, B<--loose>
  132.  
  133. Print a blank line after a C<=head1> heading.  Normally, no blank line is
  134. printed after C<=head1>, although one is still printed after C<=head2>,
  135. because this is the expected formatting for manual pages; if you're
  136. formatting arbitrary text documents, using this option is recommended.
  137.  
  138. =item B<-m> I<width>, B<--left-margin>=I<width>, B<--margin>=I<width>
  139.  
  140. The width of the left margin in spaces.  Defaults to 0.  This is the margin
  141. for all text, including headings, not the amount by which regular text is
  142. indented; for the latter, see B<-i> option.
  143.  
  144. =item B<-o>, B<--overstrike>
  145.  
  146. Format the output with overstruck printing.  Bold text is rendered as
  147. character, backspace, character.  Italics and file names are rendered as
  148. underscore, backspace, character.  Many pagers, such as B<less>, know how
  149. to convert this to bold or underlined text.
  150.  
  151. =item B<-q> I<quotes>, B<--quotes>=I<quotes>
  152.  
  153. Sets the quote marks used to surround CE<lt>> text to I<quotes>.  If
  154. I<quotes> is a single character, it is used as both the left and right
  155. quote; if I<quotes> is two characters, the first character is used as the
  156. left quote and the second as the right quoted; and if I<quotes> is four
  157. characters, the first two are used as the left quote and the second two as
  158. the right quote.
  159.  
  160. I<quotes> may also be set to the special value C<none>, in which case no
  161. quote marks are added around CE<lt>> text.
  162.  
  163. =item B<-s>, B<--sentence>
  164.  
  165. Assume each sentence ends with two spaces and try to preserve that spacing.
  166. Without this option, all consecutive whitespace in non-verbatim paragraphs
  167. is compressed into a single space.
  168.  
  169. =item B<-t>, B<--termcap>
  170.  
  171. Try to determine the width of the screen and the bold and underline
  172. sequences for the terminal from termcap, and use that information in
  173. formatting the output.  Output will be wrapped at two columns less than the
  174. width of your terminal device.  Using this option requires that your system
  175. have a termcap file somewhere where Term::Cap can find it and requires that
  176. your system support termios.  With this option, the output of B<pod2text>
  177. will contain terminal control sequences for your current terminal type.
  178.  
  179. =item B<-w>, B<--width=>I<width>, B<->I<width>
  180.  
  181. The column at which to wrap text on the right-hand side.  Defaults to 76,
  182. unless B<-t> is given, in which case it's two columns less than the width of
  183. your terminal device.
  184.  
  185. =back
  186.  
  187. =head1 DIAGNOSTICS
  188.  
  189. If B<pod2text> fails with errors, see L<Pod::Text> and L<Pod::Simple> for
  190. information about what those errors might mean.  Internally, it can also
  191. produce the following diagnostics:
  192.  
  193. =over 4
  194.  
  195. =item -c (--color) requires Term::ANSIColor be installed
  196.  
  197. (F) B<-c> or B<--color> were given, but Term::ANSIColor could not be
  198. loaded.
  199.  
  200. =item Unknown option: %s
  201.  
  202. (F) An unknown command line option was given.
  203.  
  204. =back
  205.  
  206. In addition, other L<Getopt::Long> error messages may result from invalid
  207. command-line options.
  208.  
  209. =head1 ENVIRONMENT
  210.  
  211. =over 4
  212.  
  213. =item COLUMNS
  214.  
  215. If B<-t> is given, B<pod2text> will take the current width of your screen
  216. from this environment variable, if available.  It overrides terminal width
  217. information in TERMCAP.
  218.  
  219. =item TERMCAP
  220.  
  221. If B<-t> is given, B<pod2text> will use the contents of this environment
  222. variable if available to determine the correct formatting sequences for your
  223. current terminal device.
  224.  
  225. =back
  226.  
  227. =head1 SEE ALSO
  228.  
  229. L<Pod::Text>, L<Pod::Text::Color>, L<Pod::Text::Overstrike>,
  230. L<Pod::Text::Termcap>, L<Pod::Simple>
  231.  
  232. The current version of this script is always available from its web site at
  233. L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
  234. Perl core distribution as of 5.6.0.
  235.  
  236. =head1 AUTHOR
  237.  
  238. Russ Allbery <rra@stanford.edu>.
  239.  
  240. =head1 COPYRIGHT AND LICENSE
  241.  
  242. Copyright 1999, 2000, 2001, 2004, 2006 by Russ Allbery <rra@stanford.edu>.
  243.  
  244. This program is free software; you may redistribute it and/or modify it
  245. under the same terms as Perl itself.
  246.  
  247. =cut
  248.